<script src="http://platform.twitter.com/widgets.js" type="text/javascript"></script>

<div>

  <a href="http://twitter.com/share?url=http%3A%2F%2Fdev.twitter.com&amp;via=your_screen_name" class="twitter-share-button">Tweet</a>

</div>

<script src="http://platform.twitter.com/widgets.js" type="text/javascript"></script>

<div>

   <a href="http://twitter.com/share" class="twitter-share-button"

      data-url="http://dev.twitter.com/pages/tweet_button"

      data-via="your_screen_name"

      data-text="Checking out this page about Tweet Buttons"

      data-related="anywhere:The Javascript API"

      data-count="vertical">Tweet</a>

</div>

詳しい解説はW3CやSafari公式をご覧ください。

DeviceOrientation Event Specification
http://dev.w3.org/geo/api/spec-source-orientation.html

Safari Developer Library
DeviceMotionEvent Class Reference
DeviceOrientationEvent Class Reference

var geocoder:ClientGeocoder = new ClientGeocoder();

geocoder.addEventListener(GeocodingEvent.GEOCODING_SUCCESS, handleGeocodingSuccess);

geocoder.addEventListener(GeocodingEvent.GEOCODING_FAILURE, handleGeocodingFailure);

geocoder.geocode("投稿者の住所or地名");

private function handleGeocodingSuccess(event:GeocodingEvent):void

{

　　var placemarks:Array = event.response.placemarks;

　　trace(placemarks[0].point); //緯度、経度

}

詳しくは
http://code.google.com/apis/maps/documentation/flash/services.html#Geocoding

参考サイト
http://twittervision.com/
http://twittervision.com/maps/show_3d
デモサンプル
http://code.google.com/apis/maps/documentation/flash/demogallery.html
Google Maps API for Flashドキュメント
http://code.google.com/intl/ja/apis/maps/documentation/flash/intro.html
Twitter API 仕様書 (勝手に日本語訳シリーズ)
http://watcher.moe-nifty.com/memo/2007/04/twitter_api.html

<?xml version="1.0" encoding="UTF-8" ?>

　　<Module>

　　　　<ModulePrefs title="タイトル">

　　　　<Require feature="flash" />

　　</ModulePrefs>

　　<Content type="html"><![CDATA[



　　　　<div id="flashContent"></div>

　　　　<script type="text/javascript">

　　　　gadgets.util.registerOnLoadHandler(function () {

　　　　var element = document.getElementById("flashContent");

　　　　var uri = "SWFのURL";

　　　　gadgets.flash.embedFlash(uri, element, 9,

　　　　{ width: 幅, height: 高さ ,id: "flashobject",

　　　　allowScriptAccess: "always",

　　　　allowNetworking: "all",

　　　　wmode: "transparent" });

　　　　</script>



　　]]></Content>

</Module>

swfが表示されない、JavascriptとFlashのやりとりができない、外部サービス呼び出しがおかしいなどの
トラブルはこちらが参考になります。
http://mixi.jp/view_bbs.pl?id=41567209&comm_id=3217244&page=all
http://mixiapp.rash.jp/wp/?p=72

Flashからmixi opensocial JavaScript API にアクセスするライブラリ「flixi」（フリクシィ）もあるみたいです。
http://www.serialgames.co.jp/~jun/mixi/flixi/index.html

取得できるデータはこちら
http://developer.mixi.co.jp/appli/javascript-api
占いなんかは必須ですが、インストールユーザー・閲覧者のmixiプロフィール、マイミクシィ・コミュニティ一覧などなど。

ガジェットサイズは横幅212px、縦幅は上限212pxとなってます。
（※iFrameとして表示されるのでFlashサイズはそれ以上で作ってもいけそう。スクロールは出るけど。）
アプリは最大3つまでしか登録できません。

/**

 * FlickrAPI

 * 

 * @alt

 * update '09/1/6

 * 

 */

 

import mx.utils.Delegate;

import mx.events.EventDispatcher;

import org.casaframework.load.data.xml.XmlLoad;

import org.casaframework.util.XmlUtil;





class com.alt.FlickrAPI extends MovieClip

{

    

    //--------------------------------------

    // 変数定義

    //--------------------------------------

    public var addEventListener:Function;

    public var removeEventListener:Function;

    private var dispatchEvent:Function;

    

    private var xmlUrl:String;

    private var xmlLoad:XmlLoad;

    public var xmlArray:Array;

    

    public var idArray:Array = new Array();

    public var ownerArray:Array = new Array();

    public var secretArray:Array = new Array();

    public var serverArray:Array = new Array();

    public var farmArray:Array = new Array();

    public var titleArray:Array = new Array();

    public var ispublicArray:Array = new Array();

    public var isfriendArray:Array = new Array();

    public var isfamilyArray:Array = new Array();

    public var imgArray:Array = new Array();

    

    public static var LOAD_COMPLETE:String = "onLoadComplete";

    public static var LOAD_INIT:String = "onLoadInit";

    public static var LOAD_ERROR:String = "onLoadError";

    private var OUTPUT:Boolean = false; //traceしない

    

    

    //--------------------------------------

    // コンストラクタ

    //--------------------------------------

    public function FlickrAPI( apikey:String, keyword:String, per_page:Number, page:Number )

    {

        //crossdomainの読み込み

        System.security.loadPolicyFile("http://api.flickr.com/crossdomain.xml");

        System.security.loadPolicyFile("http://farm1.static.flickr.com/crossdomain.xml");

        System.security.loadPolicyFile("http://farm2.static.flickr.com/crossdomain.xml");

        System.security.loadPolicyFile("http://farm3.static.flickr.com/crossdomain.xml");

        System.security.loadPolicyFile("http://farm4.static.flickr.com/crossdomain.xml");

        

        EventDispatcher.initialize(this);

        

        loadXML( apikey, keyword, per_page, page );

    }

    

    

    //--------------------------------------

    // XMLロード

    //--------------------------------------

    private function loadXML( apikey:String, keyword:String, per_page:Number, page:Number ):Void

    {

        

        xmlUrl = "http://api.flickr.com/services/rest/?method=flickr.photos.search" + 

                                                                                        

                                                                                        "&api_key=" + apikey + 

                                                                                        "&format=" + "rest" + 

                                                                                        "&license=" + "1,2,3,4,5,6" + 

                                                                                        "&sort=" + "interestingness-desc" + 

                                                                                        "&extras=" + "license,owner_name,o_dims,original_format" + 

                                                                                        "&tags=" + keyword + //&text= or &tag=

                                                                                        "&per_page=" + per_page + 

                                                                                        "&page=" + page;

        

        xmlLoad = new XmlLoad(xmlUrl + getRandomQuery());

        xmlLoad.addEventObserver(this, XmlLoad.EVENT_LOAD_COMPLETE, 'onXmlLoadComplete');

        xmlLoad.addEventObserver(this, XmlLoad.EVENT_LOAD_ERROR, "onXmlLoadError");

        xmlLoad.start();

        

        if (this.OUTPUT)

        {

            trace("/----------------------------------");

            trace("Flick APIロード開始");

        }

    }

    

    

    //--------------------------------------

    // XMLロード完了

    //--------------------------------------

    private function onXmlLoadComplete():Void

    {

        if (this.OUTPUT)

        {

            trace("Flick APIロード完了");

            trace("----------------------------------/");

        }

        

        dispatchEvent( { type: FlickrAPI.LOAD_COMPLETE } );

        xmlArray = XmlUtil.xmlToObject(xmlLoad.getXml())['rsp'][0]['photos'][0]['photo'];

        initXML();

    }

    

    

    //--------------------------------------

    // XMLロードエラー

    //--------------------------------------

    function onXmlLoadError():Void

    {

        if(this.OUTPUT)   trace("Flick APIロードエラー");

        dispatchEvent( { type: FlickrAPI.LOAD_ERROR } );

    }

    

    

    //--------------------------------------

    // XML初期設定

    //--------------------------------------

    private function initXML():Void

    {

        for(var i:Number = 0; i<xmlArray.length; i++)

        {

            idArray.push(xmlArray[i].id);

            ownerArray.push(xmlArray[i].owner);

            secretArray.push(xmlArray[i].secret);

            serverArray.push(xmlArray[i].server);

            farmArray.push(xmlArray[i].farm);

            titleArray.push(xmlArray[i].title);

            ispublicArray.push(xmlArray[i].ispublic); //公開1非公開0

            isfriendArray.push(xmlArray[i].isfriend);

            isfamilyArray.push(xmlArray[i].isfamily);

            

            var img:String = "http://farm" + farmArray[i] + ".static.flickr.com/" + serverArray[i] + "/" + idArray[i] + "_" + secretArray[i] + "_m.jpg"; //_m.jpgは大きさを変更できる　"s","t","m","-","b"

            imgArray.push(img);

        }

        

        dispatchEvent( { type: FlickrAPI.LOAD_INIT } );

    }

    

    

    //--------------------------------------

    // getter

    //--------------------------------------

    public function get id():Array { return idArray; }

    public function get owner():Array { return ownerArray; }

    public function get secret():Array { return secretArray; }

    public function get server():Array { return serverArray; }

    public function get farm():Array { return farmArray; }

    public function get title():Array { return titleArray; }

    public function get ispublic():Array { return ispublicArray; }

    public function get isfriend():Array { return isfriendArray; }

    public function get isfamily():Array { return isfamilyArray; }

    public function get img():Array { return imgArray; }

    

    

    //--------------------------------------

    // キャッシュクリア用

    //--------------------------------------

    private function getRandomQuery():String

    {

        var myDate:Date = new Date();

        return (_root._url.substr(0, 5) == "http:" || _root._url.substr(0, 6) == "https:") ? "?" + String(myDate.getTime()) : "";

    }

}

//----------------------------------

//  import

//----------------------------------

import flash.display.BitmapData;

import com.alt.FlickrAPI;





//----------------------------------

//  変数定義

//----------------------------------

var flickr:FlickrAPI = new FlickrAPI( "xxxxxxxxxx", "cow", 50, 1 );

//（ あなたのAPIアプリケーションキー, 検索するときのタグ名, 検索1回あたりの取得件数, 出力ページ番号 ）

var image_mcl:MovieClipLoader = new MovieClipLoader();

var mclListener:Object = { }; //画像読み込みのリスナー





//----------------------------------

//  参照

//----------------------------------

var _this:MovieClip = this;





//----------------------------------

//  関数定義

//----------------------------------

function onLoadCompleteHandler():Void

{

    //trace("complete");

}

function onLoadInitHandler():Void

{

    //flickr.img[i]   //画像のurl

    

    for (var i:Number=0; i < flickr.img.length; i++)

    {

        var mc:MovieClip = _this["image" + i + "_mc"];

        image_mcl.addListener(mclListener);

        image_mcl.loadClip(flickr.img[i], mc);

    }

}

function onLoadErrorHandler():Void

{

    //trace("error");

}





//----------------------------------

//  初期設定

//----------------------------------

Stage.scaleMode ="noScale";

Stage.align = "TL";



//画像コンテナ配置

for (var i:Number=0; i < 40; i++)

{

    var mc:MovieClip = _this.createEmptyMovieClip("image" + i + "_mc", this.getNextHighestDepth());

    mc._x = 110 * (i % 5);

    mc._y = 110 * Math.floor(i / 5);

}



//Flickr

flickr.addEventListener(FlickrAPI.LOAD_INIT, onLoadInitHandler);

flickr.addEventListener(FlickrAPI.LOAD_COMPLETE, onLoadCompleteHandler);

flickr.addEventListener(FlickrAPI.LOAD_ERROR, onLoadErrorHandler);

mclListener.onLoadStart = function(target:MovieClip):Void

{

};

mclListener.onLoadComplete = function(target:MovieClip):Void

{

};

mclListener.onLoadInit = function(target:MovieClip):Void

{

    target._width = 100;

    target._height = 100;

};

var xmlURL:String = "crossdomain-proxy.php?url=http://twitter.com/statuses/public_timeline.xml";

xmlLoader = new URLLoader();

xmlLoader.load(new URLRequest(xmlURL));

package

{

    import flash.display.MovieClip;

    import flash.display.Stage;

    import flash.display.StageAlign;

    import flash.display.StageScaleMode;

    import flash.geom.Point;

    import flash.events.Event;

    import flash.events.MouseEvent;

    import com.google.maps.controls.OverviewMapControl;

    import com.google.maps.MapEvent;

    import com.google.maps.MapMouseEvent;

    import com.google.maps.Map;

    import com.google.maps.MapType;

    import com.google.maps.LatLng;

    import com.google.maps.LatLngBounds;

    import com.google.maps.ProjectionBase;

    import com.google.maps.interfaces.IProjection;

    import com.google.maps.interfaces.IMapType;

    import com.google.maps.controls.MapTypeControl;

    import com.google.maps.controls.ZoomControl;

    import com.google.maps.controls.PositionControl;

    import com.google.maps.overlays.Marker;

    import com.google.maps.overlays.MarkerOptions;

    import com.google.maps.styles.StrokeStyle;

    import com.google.maps.styles.FillStyle;

    import com.google.maps.overlays.Polyline;

    import com.google.maps.overlays.PolylineOptions;

    import com.google.maps.overlays.EncodedPolylineData;

    

    public class GoogleMap1 extends MovieClip

    {

        private const API_KEY:String = "あなたのAPIキー"; //APIキー

        private var container:MovieClip;

        private var map:Map;

        

        public function GoogleMap1()

        {

            initMap();

        }

        

        private function initMap():void

        {

            //コンテナ作成

            container = new MovieClip();

            container.x = container.y = 0;

            addChild(container);

            

            //Google MAP 作成

            map = new Map();

            map.key = API_KEY; //APIキー

            map.language = "ja"; //言語

            map.setSize(new Point(stage.stageWidth, stage.stageHeight));    //地図サイズ設定

            map.addControl(new PositionControl()); //ポジションキーボタン

            map.addControl(new ZoomControl()); //拡大縮小スライダー

            map.addControl(new MapTypeControl()); //地図タイプセレクトボタン

            map.addControl(new OverviewMapControl()); //右下オーバービューコントローラー

            map.addEventListener(MapEvent.MAP_READY, onMapReady, false, 0, true); //イベント設定

            container.addChild(map);

        }

        

        //地図生成完了イベント

        private function onMapReady(e:MapEvent):void

        {

            map.removeEventListener(MapEvent.MAP_READY, onMapReady);

            

            //初期表示設定

            map.enableScrollWheelZoom(); //マウスホイールで拡大縮小できる

            map.enableContinuousZoom(); //スムースな拡大縮小ができる

            

            //座標セット

            map.setCenter(

                                new LatLng(35.6586317, 139.7454109), //座標

                                14, //拡大率

                                MapType.NORMAL_MAP_TYPE //地図タイプ

            );

            

            //マーカー追加

            addMarkers();

            

            //直線ラインを引く

            addDrawLine();

            

            //地図ラインを引く

            addMapLine();

            

            //ステージ設定

            initStage();

        }

        

        //マーカー配置

        private function addMarkers():void

        {

            //マーカー1設定

            var marker1:Marker = new Marker(

                        new LatLng(35.6586317, 139.7454109),

                        new MarkerOptions({strokeStyle: new StrokeStyle({color: 0xFF0000}), fillStyle: new FillStyle({color: 0xFFFFFF, alpha: 1}), radius:10, hasShadow:true})

            );

            marker1.addEventListener(MapMouseEvent.CLICK, clicked, false, 1, true);

            

            //マーカー2設定

            var marker2:Marker = new Marker(

                        new LatLng(35.6602616, 139.7295483)

            );

            marker2.addEventListener(MapMouseEvent.CLICK, clicked, false, 1, true);

            

            //マーカー配置

            map.addOverlay(marker1);

            map.addOverlay(marker2);

        }

        

        //マーカークリックイベント

        private function clicked(event:MapMouseEvent):void

        {

            map.panTo(event.target.getLatLng()); //マーカー座標へ移動

        }

        

        

        //直線ラインを引く

        private function addDrawLine():void

        {

            // Polyline overlay.

            var polyline:Polyline = new Polyline([

                    new LatLng(35.6586317, 139.7454109),

                    new LatLng(35.6602616, 139.7295483)

                    ], new PolylineOptions({ strokeStyle: new StrokeStyle({

                    color: 0xFF0000,

                    thickness: 4,

                    alpha: 0.7})

            }));

            map.addOverlay(polyline);

        }

        

        

        //地図に沿ったラインを引く

        private function addMapLine():void

        {

            // エンコードされた座標値

            var encodedPoints:String = "kqsxE{_}sYiAm@kCbHk@`E|An@fNuFpJqEcCwB??{DOwEbAiByAy@vC"

            

            // エンコードされたズームレベル値

            var encodedLevels:String = "BBBBBBBBBBBBB";



            

            var encodedPolyline:Polyline = Polyline.fromEncoded(

                new EncodedPolylineData(

                                        encodedPoints, // エンコードされた座標値

                                        32, // 線の描画精度

                                        encodedLevels, // エンコードされたレベル

                                        4

                ), 

                new PolylineOptions({ strokeStyle: new StrokeStyle({

                                        color: 0x00FF00, // 線の色

                                        thickness: 10, // 線の太さ

                                        alpha: 0.5 // 線の透明度

                })

            }));

            map.addOverlay(encodedPolyline);

        }

        

        

        //ステージ設定

        private function initStage():void

        {

            stage.showDefaultContextMenu = false;

            stage.scaleMode = StageScaleMode.NO_SCALE;

            stage.align = StageAlign.TOP_LEFT;

            stage.addEventListener(Event.RESIZE, stageResizeListener);

            stage.addEventListener(MouseEvent.MOUSE_MOVE, mouseMoveListener, true);

            

            map.setSize(new Point(stage.stageWidth, stage.stageHeight));

        }

        

        //マウス移動イベント

        private function mouseMoveListener(e:MouseEvent):void

        {

            //マウスの座標取得

            var nowLL:LatLng = map.fromViewportToLatLng(new Point(mouseX, mouseY));

            //trace(nowLL.lat()+" , "+nowLL.lng());

        }

        

        //ステージリサイズイベント

        private function stageResizeListener(e:Event):void

        {

            map.setSize(new Point(stage.stageWidth, stage.stageHeight));

        }

    }

}

Security.loadPolicyFile("http://api.flickr.com/crossdomain.xml");

Security.loadPolicyFile("http://farm1.static.flickr.com/crossdomain.xml");

Security.loadPolicyFile("http://farm2.static.flickr.com/crossdomain.xml");

Security.loadPolicyFile("http://farm3.static.flickr.com/crossdomain.xml");

Security.loadPolicyFile("http://farm4.static.flickr.com/crossdomain.xml");

btn.addEventListener(MouseEvent.CLICK, function(e:MouseEvent):void{

        toggleFullScreen();

});

function toggleFullScreen():void

{

    if(stage.displayState == StageDisplayState.NORMAL)

    {

        stage.displayState = StageDisplayState.FULL_SCREEN;

    }

    else

    {

        stage.displayState = StageDisplayState.NORMAL;

    }

}

so.addParam("allowFullScreen", "true");

var req:URLRequest = new URLRequest("http://api.satoru.net/text2voice/");

    var loader:URLLoader = new URLLoader();

    var variables:URLVariables = new URLVariables();

    variables.text = txt.text;

    req.method = URLRequestMethod.GET;

    req.data = variables;

    loader.load(req);

    loader.addEventListener(Event.COMPLETE, function(e:Event):void{

        

        //音声ロード完了したら

        var sReq:URLRequest = new URLRequest(loader.data);  

        var sd:Sound = new Sound();  

        sd.load(sReq);  

        var sc:SoundChannel = sd.play();  

    });